Вебхук. Путь Телеграма

Публикация № 1128028

Разработка - Системная интеграция - Внешние источники данных

Телеграм telegram вебхук webhook. бот для телеграм + на http сервис телеграма webhook

Долгое (на самом деле нет) и нелегкое путешествие телеграма к неведомым (из за РКН) конфигурациям 1С. Памятка себе.

Ну вот, когда где-нибудь едешь, то в голове столько мыслей, что написать, а когда садишься писать, где вы, все мысли?!

Вдох

Выдох

Поехали (с)

 

Давно хотел написать что нибудь интересно, но все интересно, что мне поддавалось, было уже давно написано. Про связку телеграм + 1с тоже уже все давно написано, причем раз в несколько недель выходит новая публикация, но мне эта разработка так понравилась, что, пожалуй, напишу еще одну. Но хватит лирики.

P.S. Поскольку вышел там какой то закон, все картинки рисовал сам.

 

Сказ о том, как телеграм путь к 1С искал.

Однажды я подумал... и понеслось.

...

А потом думаю - "оповещать покупателей в телеграме, из 1с, о статусах заказов было бы прикольно". Но на деле оказалось все куда интересней. Получение данных из 1с для сотрудников! Эта идея показалась мне очень интересной. Есть один маааааленький минус... телеграм запрещен в РФ. Вайбер? Да, как вариант. Может быть когда нибудь) 

"Я смутно помню тот момент, это был не легкий выбор. Все как в туманном сне, я плохо контролирую свое тело, вокруг паника, нужно встать и идти. В голове была одна мысль - нельзя останавливаться. Нужно было выбрать направление. Передо мной появился он... протянув руку и раскрыв кулак, он сказала:

- Выберешь голубую, и история закончится прямо здесь.

 На ладони лежали две таблетки - голубая и красная. Это была точка не возврата " (с) bot_telegram

Конечно, для себя я сразу определил, что буду пользоваться вебхуком, когда узнал, что такое возможно) Итак, что нам понадобится для вебхука:

1. Сервер apach

2. Статический(белый ip) на сервере. 

3. Виртуальный сервер - если у вас заблокирован телеграм. 

4. Прямые руки.

5. Чашечка чая.

6. Две чашечки кофе. 

Теперь подробней... По факту я конечно начал с шестого пункта, но здесь пойдем по порядку.

1. Сервер

Качаем apach 2.4 и vc_redist с этого сайта. Не перепутайте разрядности(версия apach на момент написания статьи).

- Разархивируем папку apach24 в корень системного диска. По умолчанию конфигурационный файл настроен на диск C:\, так что если у вас нет такого диска, или у системного диска другая буква, необходимо будет заменить это в файле.

Открываем файл C:\Apache24\conf\httpd.conf блокнотом. Находим в нем строку Listen 80, и ниже нее добавляем допустим Listen 8018. Именно на порт 8018 будет идти запрос. Можете установить какой предпочитаете.

- Установим vc_redist

- Для установки службы, откроем командную строку от имени администратора. Перейдем в каталог bin командой:

cd C:\Apache24\bin

и следующей командой установим службу:

httpd.exe -k install

Кажись служба установлена, ну зайдем в список служб проверим на всякий случай) Если не получилось, то выполним пункт назначения 5 или 6, на ваше усмотрение, и попробуем еще раз.

2. Статический ip

Здесь все еще проще. Чтобы телеграмму было куда отправить телеграм мог отправить запрос, нужен статический ip все потому что он белый

Если он уже есть - хорошо, если нет - нужно как то чтобы был. Далее пробрасываем порт на наш сервер apach на порт 8018, чтобы открыв наш адрес через белый ip, мы увидели что It works!

PS Если не получиться, но вы уверены, что все сделали правильно, то проверьте не блокирует ли ваш запрос антивирус или брандмауэр.

3. VPS или Виртуальный сервер. 

Здесь все достаточно просто - поскольку обращения телеграма к нашему серверу будет блокировать провайдер, то нам нужен посредник. Есть замечательное видио. по настройки этого посредника, так же у автора на сайте есть статья по этому видио, откуда можно скопировать все команды. Я арендовал VPS в другом месте, так как мне показалось, что рекомендуемый VPS дороговат. Я нашел за 3 евро в месяц. Так же выбрал ОС debian и все настраивал полностью по видио. Все получилось! 

Единственное, что у меня не получилось - это установить вебхук))))))))))) Так как в видио этого нет, а я не совсем бумбум) Но я не сдрейфил, связался с автором и попросил помочь, за что ему большое спасибо)

Если у вас на VPS не установлен curl(а если вы только развернули сервер, то скорей всего так и будет), нужно выполнить команду:

apt install curl

И установка вебхука:

curl -F "url=https://IP_VPS:Port" -F "certificate=@/etc/ssl/certs/nginx-selfsigned.crt" "https://api.telegram.org/bot{ТокенБота}/setWebhook"

IP_VPS - ip ващего виртуального сервера.

Port - порт, который установили в конфигурационном файле telegram.conf.

nginx-selfsigned.crt - сгенерированный сертификат. 

Не забудьте указать порт, при установки вебхука, а то я порядком так тупил в этот момент)))

Если кому то интересно, могу продлить аренду еще на пару месяцев, и попробовать пробросить порт на ваш ip, исключительно для тестов. Но не уверен, что у меня это получится) Если что, пишите в лс, можем попробовать))

4. Да начнется веселье....

Ну да ладно, будем откровенны - прямые руки нужны на каждом пункте этой эпопеи. И даже щелчок Таноса здесь не поможет.

Предположим что бота вы уже создали. Это делается довольно просто и есть куча мануалов, а еще есть хорошая статья.  

Теперь, в 1с. Запускаем конфигуратор от имени администратора

Нам нужно создать http сервис, который будет принимать запросы телеграма. Корневой каталог укажем bot_telegram

 

На закладке Шаблоны URL добавим шаблон, предположим ОбработатьВходящиеСообщение, с двумя методами GET и POST.

В обработчике GET напишем следующий код:

Ответ = Новый HTTPСервисОтвет(200);
Ответ.Заголовки.Вставить("Content-Type","text/html; charset=utf-8");
Попытка
	Ответ.УстановитьТелоИзСтроки("Связь есть, продолжаем");
Исключение
	Ответ.КодСостояния = 400;
	Ответ.УстановитьТелоИзСтроки(ОписаниеОшибки());
КонецПопытки;
Возврат Ответ;

Обновим конфигурацию базы данных. Теперь необходимо опубликовать наш сервис. Переходим на закладку Администрирование - Публикация на веб сервере... Заполняем необходимые данные

Сразу же включим отладку веб сервера. Перейдем на закладку Прочее

Жмем Опубликовать, и перезагружаем службу apach(в моем случае службу приходилось перезагружать каждый раз, когда вносили изменения в конфигурацию). 1с предложит самой перезапустить службу, но не верьте ей, сделайте это сами. Переходим по нашему VPS IP Если все сделано правильно, то должны увидеть наше сообщение:

Теперь напишем команду приветствия нового пользователя. Переходим в обработчик POST запроса. Сразу скажу что при принятии сообщения, нужно различать текстовую команду, от клавиатурной команды сообщения (inline клавиатура). Я делаю это проверкой свойства структуры callback_query. Функцией РазобратьПакет json разберем пакет на структуры.

Добавил справочник Боты, куда заношу токен, и сервер. Потом если в параметрах процедуры отправки сообщения эти параметры пустые, тогда получаю бота по умолчанию, у которого активен соответствующий реквизит. Вы же можете прописать настройки бота в коде для тестирования, и передавать в параметрах. Во вложении будет конфигурация со справочником.

Функция ОбработатьВходящиеСообщенияPOST(Запрос)
	
	ПакетСообщения = Разобратьпакет(Запрос.ПолучитьТелоКакСтроку());
	ПакетСообщения = ?(ПакетСообщения.Свойство("callback_query"), ПакетСообщения.callback_query, ПакетСообщения); // Если ответ с inline клавиатуры, тогда берет подпакет
	Подписчик = ПакетСообщения.message.chat.id;
	Если ПакетСообщения.message.Свойство("text") Тогда 															  // Если нет текста то ничего не делаем
		Если ПакетСообщения.Свойство("data") Тогда 																  // Если есть свойство data значит ответ пришел с inline клавиатуры
			//ОбработатьКомандуinline(ПакетСообщения, Подписчик);
		Иначе
			Если ПакетСообщения.message.text = "/start" Тогда														  // Определяем какую команду отправил пользователь. первая команда всегда /start, так как пользователь только подписался
				ТекстСообщения = "Добро пожаловать в чат =/";
				Успешно = Неопределено;
				Кнопки = СформироватьМассивКомандКлавиатуры();														  // Сформируем команды начальной клавиатуры 
				ОтправитьСообщениеПользователю(Подписчик,,,ТекстСообщения,Успешно,,Кнопки);
			ИначеЕсли ПакетСообщения.message.text = "ЕстьCHO??" Тогда
				//ПоказатьПодписчикуinlineКлавиатуру(Подписчик);
			Иначе
				//ОтветКомандаНеНайдена(Подписчик, Строка(ПакетСообщения.message.text));
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	
	Ответ = Новый HTTPСервисОтвет(200);
	Возврат Ответ;
	
КонецФункции

Функция Разобратьпакет(СтрокаJSON) 
	
	Чтение = Новый ЧтениеJSON;
	Чтение.УстановитьСтроку(СтрокаJSON);
	Данные = ПрочитатьJSON(Чтение, Ложь);
	Чтение.Закрыть();	
	
	Возврат Данные;
	
КонецФункции

Функция СформироватьМассивКомандКлавиатуры()
	
	МассивКнопок = Новый Массив;
	МассивКнопок.Добавить("ЕстьCHO??");
	Строки = Новый Массив;
	Строки.Добавить(МассивКнопок);
	КнопкиJs = ЗаписатьJS(Новый Структура("keyboard", Строки));
	
	Возврат КнопкиJs;
	
КонецФункции

Функция ЗаписатьJS(СтруктураJS)
	
	ЗаписьJSON = Новый ЗаписьJSON;
	ЗаписьJSON.УстановитьСтроку();
	ЗаписатьJSON(ЗаписьJSON,СтруктураJS);
	Возврат ЗаписьJSON.Закрыть();	

КонецФункции

Процедура ОтправитьСообщениеПользователю(id_Чата, Токен = Неопределено, Сервер = Неопределено, Сообщение, Успешно = Неопределено, ПутьФайла = Неопределено, Кнопки = Неопределено) Экспорт
	
	Если Токен = Неопределено Тогда
		ПолучитьБотаПоУмолчанию(Токен, Сервер);
	КонецЕсли;
	
	Если ЗначениеЗаполнено(ПутьФайла) Тогда
		//ОтправитьФайл(id_Чата, Токен, Сервер, ПутьФайла);
	Иначе
		
		ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
		ИнтернетПрокси.Установить("https","195.171.27.244",3128, "", "", Ложь);
		
		Ресурс = "bot" + Токен + "/sendMessage?chat_id=" + СтрЗаменить(Формат(id_Чата, "ЧДЦ=; ЧС=; ЧРГ=."), ".", "") + "&text=" + Сообщение+ ?(Кнопки<>Неопределено, "&reply_markup="+Кнопки ,"");
		ЗС = Новый ЗащищенноеСоединениеOpenSSL();
		
		Соединение  =  Новый HTTPСоединение(Сервер,443,,,ИнтернетПрокси,,ЗС);
		Запрос = Новый HTTPЗапрос(Ресурс);
		
		Попытка
			Ответ = Соединение.Получить(Запрос);
		Исключение
			Успешно = ОписаниеОшибки();
			Возврат;
		КонецПопытки;
		
		Успешно = Ответ.КодСостояния = 200;
	КонецЕсли;
	
КонецПроцедуры

Процедура ПолучитьБотаПоУмолчанию(Токен, Сервер)
	
	Запрос = Новый Запрос("ВЫБРАТЬ
	                      |	Боты.Токен КАК Токен,
	                      |	Боты.Сервер КАК Сервер
	                      |ИЗ
	                      |	Справочник.Боты КАК Боты
	                      |ГДЕ
	                      |	Боты.Основной");
	
	Выборка = Запрос.Выполнить().Выбрать();
	
	Выборка.Следующий();
	
	Токен 	= Выборка.Токен;
	Сервер 	= Выборка.Сервер;
	
КонецПроцедуры

Совсем забыл упомянуть, для стран где телеграм заблокирован, нужно использовать прокси. Я нашел один, который стабильно работал на момент написания статьи, и прямо в коде его прописал. Вот очень хорошая статья по этому поводу.

Обновляем конфигурацию, перезапускаем службу apach.

Так же при отправке ответа, формируется статическая клавиатура с командами, ну чтобы не писать их каждый раз.  В результате должны получить что то типа такого:

Бот у нас будет не особо доброжелательным. Ну еще бы...

Далее на нашу единственную команду клавиатуры сформируем inline клавиатуру. Смысл такой клавиатуры, что она привязана к конкретному сообщению. В текущей разработке у них нет особого смысла, но да ладно мы тут вроде как вебхук поднимаем, а не переписываемся

Процедура ПоказатьПодписчикуinlineКлавиатуру(Подписчик)
    
    ТекстСообщения = "А чо нада???";
    Успешно = Неопределено;
    Кнопки = СформироватьМассивКомандКлавиатуры_inline();
    ОтправитьСообщениеПользователю(Подписчик,,,ТекстСообщения,Успешно,,Кнопки);
        
КонецПроцедуры

Функция СформироватьМассивКомандКлавиатуры_inline()
    
    МассивКнопок = Новый Массив;
    МассивКнопок.Добавить("Картинка");
    МассивКнопок.Добавить("Аудио");
    МассивКнопок.Добавить("Документ");
    Кнопки = Новый Массив;
    Для каждого Кнопка ИЗ МассивКнопок Цикл
        Кнопки.Добавить(Новый Структура("text, callback_data", кнопка, СтрЗаменить(Кнопка, " ", "")));
    КонецЦикла;
    Строки = Новый Массив;
    Строки.Добавить(Кнопки);
    КнопкиJs = ЗаписатьJS(Новый Структура("inline_keyboard", Строки));
    Возврат КнопкиJs;


КонецФункции

Сформируется три кнопки:

Ну и раз уж на то пошло, тогда давайте напишем обработчик этих команд. Будем указывать путь в файлу, в зависимости от того, что выбрал пользователь.

Процедура ОбработатьКомандуinline(ПакетСообщения, Подписчик)
	
	Отказ = ложь;
	
	Если ПакетСообщения.data = "Картинка" Тогда
		ПутьКФайлу = "C:\fil_bot\картинка.jpg";		
		ТекстСообщения = "Ваша картинка, сЭр";
	ИначеЕсли ПакетСообщения.data = "Аудио" Тогда
		ПутьКФайлу = "C:\fil_bot\audio.mp3";
		ТекстСообщения = "Ваше аудио, сЭр";
	ИначеЕсли ПакетСообщения.data = "Документ" Тогда
		ПутьКФайлу = "C:\fil_bot\document.xlsx";
		ТекстСообщения = "Ваш документ, сЭр";
	Иначе
		Отказ = истина;
	КонецЕсли;
	
	Если Не Отказ Тогда
		ОтправитьСообщениеПользователю(Подписчик,,,ТекстСообщения,, ПутьКФайлу);
	КонецЕсли;
	
КонецПроцедуры

И процедура отправки файла, которую я честно стырил отсюда  и немного переделал(надеюсь не будут судебные иски и вот это вот все) 

Процедура ОтправитьФайл(id_Чата, Токен, Сервер, ПутьКФайлу)
    
	Файл = Новый Файл(ПутьКФайлу);
	ИмяОтправляемогоФайла = Файл.Имя;	
    
    СтрокаСоединения = "/bot" + Токен + "/sendDocument";
    
    Boundary = "----"+Строка(Новый УникальныйИдентификатор());
    
    //Определяем массив для процедуры ОбъединитьФайлы
    МассивФайловДляОбъединения = Новый Массив;
    
    //Формируем начальный фрагмент файла POST-запроса
    ИмяФайлаОтправкиНачало = ПолучитьИмяВременногоФайла("txt");
    ФайлОтправкиНачало = Новый ЗаписьТекста(ИмяФайлаОтправкиНачало, КодировкаТекста.UTF8);
    
    //Формируем конечный фрагмент файла POST-запроса
    ИмяФайлаОтправкиКонец = ПолучитьИмяВременногоФайла("txt");
    ФайлаОтправкиКонец = Новый ЗаписьТекста(ИмяФайлаОтправкиКонец, КодировкаТекста.UTF8);
    
    ТекстДляОтправки = "";
    
    ТекстДляОтправки = ТекстДляОтправки + "--"+Boundary + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""chat_id""" + Символы.ПС + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + id_Чата + Символы.ПС;
    
    ТекстДляОтправки = ТекстДляОтправки + "--"+Boundary + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "Content-Disposition: form-data; name=""document""; filename="""+ИмяОтправляемогоФайла+"""" + Символы.ПС;
    
    ФайлОтправкиНачало.ЗаписатьСтроку(ТекстДляОтправки );
    ФайлОтправкиНачало.Закрыть();
    
    МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиНачало);
    
    МассивФайловДляОбъединения.Добавить(СокрЛП(ПутьКФайлу));
    
    ТекстДляОтправки = "" + Символы.ПС;
    ТекстДляОтправки = ТекстДляОтправки + "--"+Boundary+"--";
    ФайлаОтправкиКонец.ЗаписатьСтроку(ТекстДляОтправки);
    ФайлаОтправкиКонец.Закрыть();
    МассивФайловДляОбъединения.Добавить(ИмяФайлаОтправкиКонец);
    
    ИмяФайлаОтправки = ПолучитьИмяВременногоФайла("txt");
    ОбъединитьФайлы(МассивФайловДляОбъединения, ИмяФайлаОтправки);
    
    HTTPЗапрос = Новый HTTPЗапрос;
    Заголовки = Новый Соответствие;
    
    HTTPЗапрос.Заголовки.Вставить("Connection", "keep-alive");
    HTTPЗапрос.Заголовки.Вставить("Content-Type", "multipart/form-data; boundary="+Boundary);
    
    HTTPЗапрос.УстановитьИмяФайлаТела(ИмяФайлаОтправки);
    HTTPЗапрос.АдресРесурса = СтрокаСоединения;
    
    ЗС = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows, Новый СертификатыУдостоверяющихЦентровWindows);
	ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
	ИнтернетПрокси.Установить("https","195.171.27.244",3128, "", "", Ложь);
    HTTPСоединение = Новый HTTPСоединение(Сервер,,,,ИнтернетПрокси,, ЗС);
    
    Попытка
        ОтветHTTP = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
    Исключение
		
	КонецПопытки;
	
КонецПроцедуры

И получаем то, что выбрали

Так же сделал обработку, для отправки сообщений в чат пользователя от имени бота

Как то так...

Получился какой то набор ссылок) Nо возможно этого я и хотел, так как уже при повторном поднятии вебхука, у меня не все получалось)

Мне понравилась это направление, в дальнейшем хочу реализовать отправку отчетов и получение данных из базы 1с. Единственное - не знаю в каком направлении двигаться дальше - какие отчеты отправлять, какие данные получать, для каких конфигураций. На моем предприятии данный функционал не актуален, поэтому если кому то понадобится, или у кого то есть идеи, пишите в лс или в комментарии, буду благодарен. 

Конфигурацию прикреплю во вложение. 

Разрабатывалось на платформе 8.3.15.1656, но на более низких версиях 8.3 должно работать без проблем. 

 

 

 

 

 

 

 

 

 

 

 

 

 

Используемые источники:

Установка сервера Аpache 2.4

Телеграм + 1С + Вебхуки + Апач + Самоподписанный сертификат

1С:Пирог

https://nizamov.school/

HTTP Сервисы: Путь к своему сервису. Часть 1

 

Скачать файлы

Наименование Файл Версия Размер
Вебхук. Путь Телеграма. :
.cf 16,35Kb
02.10.19
9
.cf 16,35Kb 9 Скачать

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо развёрнутое
Свернуть все
1. ex3mall 2 03.10.19 22:42 Сейчас в теме
Нужный материал.

Когда-то, надеюсь, здравый смысл восторжествует, РКН перестанет изображать муху, бьющуюся в стекло, и Телеграмм начнет работать стабильно у всех на мобилах.

Вообще на сегодняшний день Телеграм - идеальная платформа для создания групп и оповещения о событиях (например, выгрузка управленческих отчетов, опросники - для согласования коммерческих условий и договоров, или информирование о событиях для оперативного принятия решения).

Но, к сожалению, из-за опасения "А вдруг все-таки заблокируют наглухо" люди предпочитают тратить деньги на создание собственных мобильных приложений.
semagin@gmail.com; +1 Ответить
8. for_sale 855 04.10.19 14:22 Сейчас в теме
(1)
У меня вообще без проблем работает, даже без ВПН.
Ну а уж жить в этой стране без ВПН - это как-то...
2. acanta 74 03.10.19 22:51 Сейчас в теме
Вау. Раньше использовали Миранду как локальный сервер с приложением от глобального чата плюс выгонялка из 1с. Видимо проблема у них с собственным сервером.. Теперь телеграмм тоже можно и даже больше. Это очень круто.
3. kuzyara 1002 04.10.19 05:21 Сейчас в теме
4. platonov.e 91 04.10.19 07:22 Сейчас в теме
(3) Думал туда еще знак РКН пририсовать, но посмотрел на это, и удалил его)
5. serg-lom89 49 04.10.19 10:49 Сейчас в теме
отлично
Согласен счас Телега самый доступный и простой во внедрении для 1С.
Публичный Api что открыт это прекрасно
Сам много познал из https://nizamov.school/ и после него тоже занесло в дебри интеграции с веб !
Вебхук еще не использовал ,но надеюсь в ближайшее время дойдут руки.!
6. platonov.e 91 04.10.19 10:53 Сейчас в теме
(5)Успехов вам) Если что обращайтесь, постараюсь помочь) Но там вроде все просто)
7. Region102 04.10.19 11:49 Сейчас в теме
Очень рад что мои уроки пригодились. Скоро запишу полноценный курс по telegram.
platonov.e; +1 Ответить
9. dap 12 09.10.19 17:18 Сейчас в теме
У меня файловая база опубликована на IIS10
успешно приходят сообщения в 1С на HTTP сервис от Бота только в том случае, если в базе НЕТ пользователей (без авторизации)
Если завожу в базу пользователей, то соответственно getWebhookInfo - дает ошибку 401 авторизации
и сообщения от бота не приходят.

1. публиковал базу без галочки "Использовать аутентификацию ОС"
2. в IIS везде от сервера до базы анонимная авторизация ВКЛЮЧЕНА, остальные - отключены.

Поэтому вопрос. Раскройте пожалуйста тему авторизации. Как должна быть настроена авторизация, чтобы связка
HTTP сервис 1С и БОТ Телеги работала нормально. Для случая, когда в базе зарегистрированы пользователи.
10. platonov.e 91 09.10.19 20:26 Сейчас в теме
(9) Я такое на apach обходил следующим образом: В 1с заводил пользователя с необходимыми правами. В файле default.vrd прописывал логин и пароль этого пользователя, и при обращении к сервису, он автоматически авторизовывался под ним. Прописывал в атрибуте id, тег point. получалась строка такого вида:
ib="File="Каталогбазы";Usr="Пользователь";Pwd="Пароль;";"


Желательно наверное латиницей прописывать) Делал я это не для телеграма, но работало. Однако с точки зрения безопасности это не самая лучшая идея. Позже попробую найти другой способ)
11. dimasts 22 25.12.19 22:34 Сейчас в теме
Подскажите пожалуйста, а требуется ли иметь на своём сервере HTTPS? Если да то как его установить и какого уровня HTTPS будет достаточно?
12. platonov.e 91 08.01.20 16:25 Сейчас в теме
(11) Я немного не понимаю о чем вы) Если сделать все по статье, то вроде как ничего дополнительно устанавливать не нужно)
13. strafer 17.02.20 16:50 Сейчас в теме
Ошибка есть
Процедура ОбработатьКомандуinline(ПакетСообщения, Подписчик)
	
	Отказ = ложь;
	
	Если ПакетСообщения.data = "Картинка" Тогда
		ПутьКФайлу = "C:\fil_bot\картинка.jpg";		
		ТекстСообщения = "Ваша картинка, сЭр";
	ИначеЕсли ПакетСообщения.data = "Аудио" Тогда
		ПутьКФайлу = "C:\fil_bot\audio.mp3";
		ТекстСообщения = "Ваше аудио, сЭр";
	ИначеЕсли ПакетСообщения.data = "Документ" Тогда
		ПутьКФайлу = "C:\fil_bot\document.xlsx";
		ТекстСообщения = "Ваш документ, сЭр";
	Иначе
		Отказ = истина;
	КонецЕсли;
	
	Если Не Отказ Тогда
		ОтправитьСообщениеПользователю(Подписчик,,,ТекстСообщения,, ПутьКФайлу, Кнопки); // переменная Кнопки видимо тут лишняя
	КонецЕсли;
	
КонецПроцедуры
Показать
14. platonov.e 91 17.02.20 16:58 Сейчас в теме
Оставьте свое сообщение

См. также

daСклонение: склонение ФИО, должностей, чисел, прилагательных, существительных на языке 1С + ТестЦентр Промо

Универсальные функции v8 1cv8.cf Абонемент ($m)

Функция предназначена для склонения выражений, которые часто требуется при формировании печатных форм договоров и прочих печатных форм. Функция склоняет по падежам ФИО, должности, числительные, валюты, единицы измерения, предметы. Также функция склоняет глаголы и прилагательные по числам и родам и существительные по числам. Имеется режим определения рода переданного выражения. Поддержка форматной строки для вывода результата. Функция не использует внешние библиотеки и веб-сервисы, написана на чистом языке 1С, и поэтому легко встраивается в любую конфигурацию или внешнюю обработку. Правила склонения оформлены в виде таблицы и могут быть легко изменены при необходимости.

1 стартмани

14.02.2015    99090    96    daMaster    88    

Сравнение реального дохода со средним доходом из API.HH.RU

Зарплата Управленческие v8 v8::СПР ЗУП3.x УУ Абонемент ($m)

Внешняя обработка на управляемой форме для 1С:Предприятие 8.3 по интеграции с HH.RU используя HH REST API. Ключевые функции: получение списка вакансий по должностям (Ключ для работы не нужен); расчет среднего дохода; Тестирование проводилось на платформе 1С:Предприятие 8.3 (8.3.13.1513) Зарплата и управление персоналом, редакция 3.1 (3.1.11.68) совместно с API.HH.RU.

1 стартмани

11.11.2019    3646    4    solaru    2    

Конфигурация для рекламного агентства

Управление услугами и сервисом Управление взаимоотношениями с клиентами (СRM) Производство готовой продукции (работ, услуг) Управление взаимоотношениями с клиентами (СRM) Производство готовой продукции (работ, услуг) v8 Реклама, PR и маркетинг УУ Абонемент ($m)

Данная конфигурация выполнена для решения тестового задания: Цель задания: 1) Понять, на каком из клиентов сколько мы заработали;  2) Понять, по какому виду СМИ сколько мы заработали;  3) Проследить по каждой услуге: у кого за сколько купили и кому за сколько продали, с возможностью перейти в соответствующий документ. Реализовано с помощью: 1. Справочники - контрагенты, номенклатура 2. Документы - Поступление услуг, реализация услуг 3. Отчеты - отчет по контрагентам, номенклатуре и движений.

1 стартмани

21.05.2019    3927    0    solaru    0    

Загрузка номенклатуры в УТ 10.3 из Excel файла с генерацией штрихкодов

Загрузка и выгрузка в Excel Обработка справочников Оптовая торговля Розничная торговля Учет ТМЦ Оптовая торговля Розничная торговля Учет ТМЦ v8 УТ10 Россия Абонемент ($m)

Обработка позволяет генерировать новые номенклатурные позиции на основе данных из файла Excel с последующей генерацией штрихкодов (ШК). Может быть полезна при больших поступлениях товаров на склад, где ручное создание и присваивание штрихкода  (ШК) может занимать много времени.

1 стартмани

24.03.2017    7529    6    solaru    0    

Под капотом управляемых форм

Практика программирования v8 1cv8.cf Бесплатно (free)

Управляемые формы уже давно и плотно вошли в жизнь 1С-разработчика. Однако, судя по недавним публикациям на Инфостарте, многие до сих пор мало знакомы с ними. Предлагаю разобраться с тем, что же это такое.

26.08.2013    260513    0    Evil Beaver    266    

[NotaBene] Универсальный отчет по таблице значений

Практика программирования v77::ОУ v77::БУ v77::Расчет 1cv7.md Россия Абонемент ($m)

1C v.7.7 Готовое решение. Не требует настройки. Не требует допрограммирования. Данная обработка решает часто встречающуюся задачу вывода в "красивом" виде таблицы значений (полученной, например, из запроса). Поддерживается произвольное группирование данных, отключение/включение группировок, в т.ч и создание "шахматок" (типа "продажи понедельно"). Обработка может использоваться как и в отладочных целях (для нормального просмотра ТЗ), так и в составе вполне рабочих отчетов. По крайней мере, я неоднократно клиентам данную обработку ставил вместо того, чтобы каждый раз писать замороченные выводы данных. И клиенты довольны, и мне - проще...

2 стартмани

07.05.2007    27919    1    CheBurator    61